VBFAQ ^™ - Альтернативный F.A.Q. по языку


Базовая конференция FidoNet носит имя Ru.Visual.Basic и доступна на news серверах с префиксом Fido7.
Дата последнего обновления: Jun 10, 2000

---

© Автор ряда материалов и составитель: Александр Щербаков, sanqy@mtu-net.ru, sanqy@forecast.ru.
Все материалы данного VBFAQ, по отдельности, могут свободно использоваться в оригинальном или видоизмененном виде как в коммерческих, так и некоммерческих целях. VBFAQ в том виде, как он есть, может использоваться только в некоммерческих целях. Коммерческое использование VBFAQ, допустимо только с письменного согласия составителя и авторов данного документа.

Содержание

1. Справка по среде (IDE) и все, что с ней связано.
   1. "Я купил 1 диск с VB6. Вызываю хелп, ругаетца на MSDN! Плис, дайте этот MSDN скачать."
   2. Дополнительные сведения о параметрах Setup Wizard (setup.lst).
   3. Отлаживаю код и приходится часто "прыгать" по коду модуля. Можно ли упростить этот процесс?
2. Начальные сведения по языку VisualBasic.
   1. "Как засyнyть MSVBVM?0.DLL в экзешник?"
   2. Как правильно реализовать стиль Wizard?
   3. Что такое модули, и зачем они нужны?
   4. Что такое классы и с чем их едят?
3. Использование наиболее употребимых контролов VisualBasic.
   1. Использование WinSock.ocx.
4. Функции Win32API.
   1. Как сделать окно повеpх всех?
   2. "А как засyнyть пpогpаммy тyды к часикам?"
   3. Как перевести текст из DOS кодировки в WIN и наоборот?
   4. Программное переключение клавиатуры RUS/LAT.
   5. Перетаскивание формы мышкой не за заголовок.
   6. Как все же вытащить ассоциированную иконку?
   7. Можно ли на VB создать консольное приложение и если да, то как?
   8. Как создать меню с картинками?
   9. Как побороть глюк всплывающего меню, вызываемого по клику из трея?
   10. Как сделать окно неправильной формы?
   11. Как привязать программу к компьютеру?
   12. Получить изображение экрана.
   13. Как открыть дверцу (Tray) CD-Rom программно?
   14. Каким образом можно засюспендить (suspend) компьютер?
5. Использование внешних библиотек и дополнительных контролов.
   1. Как можно прочитать данные с порта или записать данные в порт?
6. Базы данных.
   1. Как работать с mdb базой, расположенной на Read/Only диске (CD-Rom)?

A. Справка по среде (IDE) и все, что с ней связано.

A1	"Я купил 1 диск с VB6. Вызываю хелп, ругаетца на MSDN! Плис, дайте этот MSDN скачать."

MSDN это не примочка для просмотра хелпа. Это и есть сам хелп. Поставляется на 3-х CD. Но желающие могут их утянуть с http://msdn.microsoft.com. ;)

Igor Kudryashov:
ХЕЛП ОТ VISUAL BASIC 6, КАК И ОТ ВСЕХ ОСТАЛЬHЫХ ПРОГРАММ, ВХОДЯЩИХ В СОСТАВ VISUAL STUDIO 98, HАХОДИТСЯ В MSDN, КОТОРЫЙ ЕСТЬ HА 4-ОМ И 5-ОМ ДИСКАХ VISUAL STUDIO. В КОМПЛЕКТ ДИСТРИБУТИВА ЛЮБОГО ПРОДУКТА VS, ПРОДАВАЕМОГО ОТДЕЛЬHО ВХОДЯТ ДВА ДИСКА MSDN. ЕСЛИ ВЫ ПРИОБРЕЛИ VB6 HА ОДHОМ ДИСКЕ, ДА ЕЩЕ С КУЧЕЙ ПРИПАМПАСОВ К HЕМУ HА ТОМ ЖЕ ДИСКЕ, ТО HА ПОМОЩЬ ("ХЕЛП") HЕ РАССЧИТЫВАЙТЕ. ТЕПЕРЬ ВАМ СЛЕДУЕТ ДОКУПИТЬ MSDN (СЕЙЧАС В ПРОДАЖЕ ПОЯВИЛСЯ MSDN 2000 HА ТРЕХ ДИСКАХ). Hу и конечно всегда можно скачать MSDN нахаляву с сайта MS. Сколько это будет Гб ты уже наверное догадался. :))

A2	Дополнительные сведения о параметрах Setup Wizard (setup.lst).

Artem Prohorov:
Откpываешь свой файл setup.lst, находишь pаздел [Setup] и добавляешь ключик ForceUseDefDir = 1, после чего установить приложение в другой фолдер будет невозможно. Чтобы изменить пyть к пpиложению, меняй стpокy DefaultDir.
Описание ключей я беpy из книги Visual Basic 6.0 Рyководство для пpофессионалов, сеpия Мастеp, Microsoft Press. Значит должны быть описанны и в MSDN. Создавать дефолтную группу нyжно пpи помощи секции [IconGroups] файла setup.lst таким вот обpазом:

   [IconGroups]
   Group0=MyTestEXE
   Group1=MyGroupNumber1

   [MyTestExe]
   Icon1=my.exe
   Title1=MyTestExe

   [MyGroupNumber1]
   Icon1=ReadMe.txt
   Title1=ReadMe
   Icon2=my.hlp
   Title2=Help

A3	Отлаживаю код и приходится часто "прыгать" по коду модуля. Можно ли упростить этот процесс?

Конечно! Вопервых VB позволяет Split окон модулей. Для это захватите продолговатую кнопочку над скроллером и тяните ее вниз. Окно будет разбито на 2 половинки, в каждой из которых можно работать с кодом. Чтобы восстановить "статус-кво", перетащите разделительную полоску на самый верх.
Другим, не менее удобным способом, является использование bookmark. Нажмите правой мышиной кнопкой в любом месте панелей VB и выберите Edit. У Вас появится новая панель, на которой будут видны 4 синих флажка. Один из них позволяет ставить/убирать метки в тексте (букмарки), два других перемещаться между букмарками и четвертый флажок убирает все букмарки.

B. Начальные сведения по языку VisualBasic.

B1	"Как засyнyть MSVBVM?0.DLL в экзешник?"

Ответ на этот вопpос и подобные емy - никак.
Даже если найдется добpая дyша, что пpоделает этy пpоцедypy для вас, то сyммаpный pазмеp нового EXE-файла бyдет pавен сyммаpномy pазмеpy исходных EXE + DLL. Чyдес не бывает! Конечно, кто-то скажет, дескать в Cи это тpебование не выполняется. Это не так. Пpосто множество сишных DLL входят в поставкy самой Windows, ведь она писалась на Си! А если на минyткy пpедставить, что Windows создавалась бы на VB? Тогда бы VB пpогpаммистам не нyжно было бы pаспpостpанять вместе со своей пpогpаммой многочисленные компоненты - только один exe! А Сишники гоpевали бы о том, что дистpибyтив самой пpостой пpогpаммы типа "hello, world!" на Си тянет на многие сотни килобайт. Вообще, pазделение на компоненты (dll/ocx) благо, а не зло. Пpедставьте, что вы yстановили 10 своих VB пpиложений на компьютеp клиента. Если каждое пpиложение pазмеpом 100кб и использyет только MSVBVM50.DLL pазмеpом 1.3Mb, то все они займyт на винчестеpе (100кб x 10 + 1300кб) 2.3Mb. Если бы исходный exe файл включал бы в себя все необходимые DLL/OCX то pазмеp занятого на жестком диске пpостpанства непомеpно возpос бы и составил бы 14 мегабайт! (нетpyдно подсчитать, из pассчета 1 комплекта = 1.4мб (100кб + 1.3мб)).

B2	Как правильно реализовать стиль Wizard?

Как правильно реализовать стиль визарда? Это где кнопочки Далее и Назад? Я делаю несколько окон по числу шагов, но постоянно лезут глюки. Например, при перетаскивании верхнего окна, под ним оказываются другие...

WizardStyle

B3	Что такое модули, и зачем они нужны?

Что такое модули? Вообще, существует 3 типа модуля:
- модуль формы;
- просто модуль;
- модуль класса.
С модулем формы обычно знакомятся делая первые шаги в программировании на VB. Упрощенно говоря, модуль формы это то окно в котором вы описываете реакцию формы на действия с ней.
Нас же интересует простой модуль (в дальнейшем просто модуль). Такой модуль может содержать только код и добавляется в проект кнопкой, изображенной на рисунке или через меню Project|Add Module.
Так зачем нам модули? Модули нужны в следующих случаях:
1. Если Вы хотите объявить глобальную переменную, т.е. переменную, видимую во всех уголках Вашего приложения, то без модуля не обойтись:

   Public MyVar As Integer

   Form1.MyVar = 5

   Dim frmX(1) As Form1
   Set frmX(0) = New Form1
   Set frmX(1) = New Form1
   Load frmX(0)
   Load frmX(1)
   frmX(0).Visible = True
   frmX(1).Visible = True

   Public Sub Main()
      Form1.Show
   End Sub

B3	Что такое классы и с чем их едят?

Тем эта столь обширна и затрагивает так много областей программирования, что ей место не в кратеньком FAQ'е, а в обстоятельной книжке. Но я попробую совместить несовместимое, и надеюсь, гуру не будут в обиде, если я опущу частности и то, что мне показалось неважным.
Что такое класс? Это совокупность методов, свойств и событий, которые образуют целостный объект.
А теперь попроще. Объект - наручные часы. Методы предназначены для установки времени на часах, установки будильника и т.д. Свойства, в нашем случае, определяют цвет корпуса, вид индикатора и т.д. Звук будильника является событием и позволяет провести определенные действия (например, снять молоко с плиты) в заданное время. Чтобы получить доступ к свойствам, методам и событиям объекта (часов), необходимо создать указатель на него, или инстанс. Если класс называется Clock, то создание экземпляра класса (инстанса) будет выглядеть так:

   Dim clk As Clock
   Set clk = New Clock

   'вызовем метод установки времени
      clk.SetTime "13:56"
   'а теперь изменим свойство "Цвет корпуса"
      clk.Color = "Gold"
   'или увеличим свойство "Цена" на 1000 баксов ;-)
      clk.Price = clk.Price + 1000

   'эта переменная видна снаружи модуля
      Public MyFirstVar As Integer
   'а эта переменная является приватной, и не видна вне модуля
      Private MySecondVar as Integer

   Public Sub CheckVar()
      MyFirstVar = 5
      MySecondVar = 7
   End Sub

   Private m_Time As String   'переменная для хранения времени

   'публичный метод установки времени
   Public Sub SetTime(a_Time As String)
      'запомним значение
         m_Time = a_Time

      'произведем какие-то действия
         . . .

   End Sub

   'публичный метод, возвращающий напряжение батарейки питания
   Public Function GetPowerState () As Single
      'определим напряжение питания батарейки
         . . .
         BatteryVoltage = 1.48   'просто эмуляция работы некоего кода

      'возвратим значение
         GetPowerState = BatteryVoltage

   End Function

      Dim sTime As String

   'установим время
      sTime = InputBox ("Введите текущее время:", "Часики", "18:16")
      clk.SetTime sTime

   'определим состояние батарей
      MsgBox clk.GetPowerState()     'в окне будет напечатано 1.48

   Public Price As Single

   clk.Price = 500    'установить стоимость часов
   MsgBox clk.Price   'выдать стоимость часов

   Private m_Price As Single

   'процедура получения цены
   Public Function GetPrice() As Single
      GetPrice = m_Price
   End Function

   'процедура установки цены
   Public Sub SetPrice(a_Price As Single)
      If a_Price <= 800 And a_Price >= 150 Then m_Price = a_Price
   End Sub

   clk.SetPrice 450      'установить стоимость часов
   MsgBox clk.GetPrice   'выдать стоимость часов

   Private m_Price As Single

   'свойство получения цены
   Public Property Get Price() As Single
      Price = m_Price
   End Property

   'свойство установки цены
   Public Property Let Price(ByVal a_Price As Single)
      If a_Price <= 800 And a_Price >= 150 Then m_Price = a_Price
   End Property

   clk.Price = 500    'установить стоимость часов
   MsgBox clk.Price   'выдать стоимость часов

   'декларируем публичный ивент
   Public Event Alarm(Melody As String)

   'некая приватная процедура, генерирующая ивент
   Private Sub GenerateAlarm()
      'некоторые действия
         . . .

      'выстреливаем ивент
         RaiseEvent Alarm("My little star.")

   End Sub

   Dim WithEvents clk As Clock
   Set clk = New Clock

   Private Sub clk_Alarm(Melody As String)

   End Sub

1. Программа будет исполняться на банкоматах фирмы MicroSo, представляющие из себя обычные компьютеры с процессором Celeron, работающие под управлением OS Windows 98.
2. Все что не упоминается в требованиях - реализуется хардверно и нас не должно заботить.
3. После опускания клиентом кредитной карточки и нажатия кнопки, банкомат должен осуществить процедуру соединения с банком по телефонной сети. Соединение может не удасться.
4. Если соединение прошло успешно, вывести клиенту состояние его счета.
5. Предоставить клиенту возможность изменить счет, как в большую, так и в меньшую сторону. После этого провести транзакцию с банком.
6. В конце работы клиент нажимает кнопку, заканчивается сеанс, происходит рассоединение с банком и клиент получает назад свою карточку.

CreditCard

C. Использование наиболее употребимых контролов VisualBasic.

C1	Использование WinSock.ocx.

Пример с описанием находится в архиве WinSock. Для работы проекта Ваш VB должен иметь компонент Microsoft WinSock Control.
Загрузите проект WinSock.vbp из каталога WinSock. В проект входят две формы: клиент и сервер. Клиент соединяется с сервером используя протокол TCP/IP и отсылает ему число из верхнего текстбокса (сумма в USD). Сервер получает число, умножает его на число из своего текстбокса (курс валюты) и возвращает результат клиенту, который отображает его в нижнем текстбоксе (сумма в рублях). Код обильно комментирован, и надеюсь вопросов не вызовет.
В качестве следующего шага, на одном компьютере загрузите проект Server.vbp из архива WinSock\Server, а на другом компьютере проект Client.vbp из каталога WinSock\Client. Если сеть настроена правильно, и вы верно указываете имя/адрес сервера, то пример заработает. Можно на разных компьютерах запускать и скомпайленные exe файлы, но в этом случае Вы не будете иметь возможности отследить в динамике работу примера.
И о плохом. ;-)
В примере опущен код, который отвечает за перехват ошибок, неизбежно возникающих при связи. Этот код Вы без труда напишете сами, используя ивент Error винсока.
И второе. При пересылке значительных объемов информации, например файла на 100Кб, он будет разбиваться на части и приниматься винсоком кусочками. Поэтому, Вы должны проверять был ли получен весь файл или нужно продолжить его прием. Самый простой путь - перед пересылкой файла удаленному винсоку отсылать заголовочек, в котором указывать имя передаваемого файла, его размер, дату и т.д.

Функции Win32API.

D1	Как сделать окно повеpх всех?

Смотpите фyнкцию API SetWindowPos.
Пpимеp использования данной фyнкции, для pазмещения окна OnTop пpедставлен в архиве TopMost.

D2	"А как засyнyть пpогpаммy тyды к часикам?"

Смотpите фyнкцию API Shell_NotifyIcon.
Поймите, чисто физически невозможно "засyнyть" пpогpаммy в тpей. Это тоже самое, как поместить ваш любимый меpседес-600 междy pамами оконного стекла! Гpамотно сфоpмyлиpованный вопpос звyчит так: "Как поместить ИКОHКУ в системный тpей (system tray)". Подробный пример находится в архиве TrayIcon. Там же лежит класс для работы с треем - TrayIcon.cls.

D3	Как перевести текст из DOS кодировки в WIN и наоборот?

Можно ручками, создав таблицу перевода. Сам так делал, сложностей нет. А можно воспользоваться готовыми АПИшными функциями OemToChar и CharToOem.

Peter Pan:

   Public Declare Function OemToChar Lib "user32" Alias "OemToCharA" _
          (ByVal lpszSrc As String, ByVal lpszDst As String) As Long

   Dim l_lReturn as Long, l_sSource as String, l_sDestination as String
   l_lReturn = oemtochar(l_sSource, l_sDestination)

От себя лишь добавлю, что есть декларация для CharToOem выглялдит так:

   Declare Function CharToOem Lib "user32" Alias "CharToOemA" _
           (ByVal lpszSrc As String, ByVal lpszDst As String) As Long

D4	Программное переключение клавиатуры RUS/LAT.

Soleiman Mostamandy:

   ' Декларация функций и констант АПИ
   Declare Function ActivateKeyboardLayout Lib "user32" _
           (ByVal HKL As Long, ByVal flags As Long) As Long
   Public Const kb_lay_ru As Long = 68748313
   Public Const kb_lay_en As Long = 67699721
       
   ' Переключить на русский язык
   x = ActivateKeyboardLayout&(kb_lay_ru, 0)

   ' Переключить на английский язык
   x = ActivateKeyboardLayout&(kb_lay_en, 0)

D5	Перетаскивание формы мышкой не за заголовок.

Для этого используются функции API ReleaseCapture и SendMessage.
Пример на эту тему находится в архиве MoveWindow.

D6	Как все же вытащить ассоциированную иконку?

Arkadiy Olovyannikov:

   Option Explicit

   Private Declare Function ExtractAssociatedIcon Lib "shell32.dll" Alias _
           "ExtractAssociatedIconA" (ByVal hInst As Long, _
           ByVal lpIconPath As String, lpiIcon As Long) As Long
   Private Declare Function DrawIcon Lib "user32" (ByVal hdc As Long, _
           ByVal x As Long, ByVal y As Long, ByVal hIcon As Long) As Long
   Private Declare Function DestroyIcon Lib "user32" _
           (ByVal hIcon As Long) As Long

   Dim sPath As String, hIcon As Long, nIcon As Long
   sPath = путь к файлу
   hIcon = ExtractAssociatedIcon(App.hInstance, sPath, nIcon)
   DrawIcon Picture1.hdc, 0&, 0&, hIcon
   DestroyIcon hIcon

D7	Можно ли на VB создать консольное приложение и если да, то как?

Используя все тот же API. ;) Например, AllocConsole, ReadConsole и т.д.
Пример находится в архиве Console.

D8	Как создать меню с картинками?

Лобовая атака с применением API функции SetMenuItemBitmaps не пройдет. Картинки в меню получаются иных цветов, нежели в исходной битмапе и это связано с особенностями реализации этой функции. Дабы избежать игры цвета, нужно с нуля, через АПИ создавать меню, что неудобно.
Примеры, что были мне присланы, реализуют другой подход, который заключается в получении hDC (хендл контекста устройства) пункта меню и перерисовывании его на лету средствами АПИ. Этот путь позволяет использовать уже готовое меню, созданное в IDE, но имеет существенный недостаток - использование сабклассинга. В готовом EXE/DLL этот недостаток непринципиален, но на стадии отладки программы способен попортить немало крови падениями VB IDE. Дабы избежать этого, никогда не завершайте работу программы нажатием на кнопку End в IDE! Используйте кнопку [x] окна, в ивенте Form_[Query]Unload которого, находится код возвращающий указатель на старый обработчик.
Примеры находятся в архивах BitmapMenu1 и BitmapMenu2. В обоих случаях реализуется примерно один и тот же механизм, но реализованный разными путями. Первый пример, несмотря на невзрачность, позволяет использовать иконки и битмапы любого размера, не только 16x16. Внешний вид второго примера более аккуратен, но без его переделки нельзя использовать битмапы, размер которых отличен от 16x16.

D9	Как побороть глюк всплывающего меню, вызываемого по клику из трея?

Вопpос: почему после вывода окна меню из subj, пpи помощи PopupMenu, не могу никак сбpосить это окно без выбоpа элемента меню? Кто-нибудь с этим сталкивался?

   SetForegroundWindow(hDlg);

   // Display the menu
   TrackPopupMenu( hSubMenu,TPM_RIGHTBUTTON,pt.x,pt.y,0,hDlg,NULL );

   PostMessage( hDlg,WM_NULL,0,0 );

D10	Как сделать окно неправильной формы?

Arkadiy Olovyannikov:
ИМХО, проще и красивее создавать регионы через Path. Hу что можно сделать через Create...Region? Эллипс? А вот как можно использовать Path:

   Private Declare Function SelectClipPath Lib "gdi32" _
           (ByVal hdc As Long, ByVal iMode As Long) As Long
   Private Declare Function BeginPath Lib "gdi32" (ByVal hdc As Long) As Long
   Private Declare Function EndPath Lib "gdi32" (ByVal hdc As Long) As Long
   Private Declare Function PathToRegion Lib "gdi32" (ByVal hdc As Long) As Long
   Private Declare Function SetWindowRgn Lib "user32" _
           (ByVal hWnd As Long, ByVal hRgn As Long, _
           ByVal bRedraw As Boolean) As Long

   Private Const RGN_COPY = 5

   Private Sub Form_Load()
      ' Don't forget to set Form.BorderStyle property to None !
      Const TXT = " Cool programm" & vbCrLf & "           from" & vbCrLf & _
                  "Cool Company" & vbCrLf & "CopyLeft by Ark"
      Dim hRgn As Long
      Font.Name = "Times New Roman"
      Font.Bold = True
      Font.Size = 60
      Width = TextWidth(TXT)
      Height = TextHeight(TXT)
      BeginPath hdc
      CurrentX = 0
      CurrentY = 0
      Print TXT

      ' Здесь вместо текста можно рисовать фигуры
      EndPath hdc
      hRgn = PathToRegion(hdc)
      SetWindowRgn hWnd, hRgn, False

      ' Hачинаем фантазировать с формой. Можно так
      Picture = LoadPicture("c:\windows\облака.bmp")
      ' А можно так
   '  dclr = 256 / (TextHeight(TXT) / 30)
   '  clr = 0
   '  For i = 120 To 120 + TextHeight(TXT) Step 30
   '     Line (0, i)-Step(5000, 0), RGB(0, 0, clr)
   '     clr = clr + dclr
   '  Next i
      ' Можно дать форме градиентную заливку и т.д.
      ' Двигаем к центру, а можно в таймере крутить
      Move (Screen.Width - Width) / 2, (Screen.Height - Height) / 2
   End Sub

D11	Как привязать программу к компьютеру?

Осуществить привязку программы проще всего к дате создания BIOS материнской платы. Адрес расположения даты в памяти: F000:FFF5. Чтобы считать дату из BIOS, воспользуйтесь нижеследующим кодом:
Dmitry Sergunin:

   Type BIOS_DATE
      s As String * 8
   End Type

   Declare Sub CopyMemory Lib "Kernel32" Alias "RtlMoveMemory" _
           (pDest As Any, pSource As Any, ByVal ByteLen As Long)

   Public Function BIOS() As Long
      Dim sDB As BIOS_DATE

      CopyMemory sDB, ByVal &HFFFF5, 8&
      BIOS = DateSerial(Mid(sDB.s, 7, 2), Mid(sDB.s, 1, 2), Mid(sDB.s, 4, 2))
   End Function

D12	Получить изображение экрана.

Функция, которая реализует эту возможность - GetDesktopWindow. Полный код выглядит так.
Это поместить в область деклараций модуля

   Public Declare Function GetDesktopWindow Lib "user32" () As Long
   Public Declare Function GetDC Lib "user32" (ByVal hWnd As Long) As Long
   Public Declare Function BitBlt Lib "gdi32" _
          (ByVal hDestDC As Long, ByVal X As Long, ByVal Y As Long, _
          ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, _
          ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
   Public Const SRCCOPY = &HCC0020

      Dim hDesk, hDeskDC
      hDesk = GetDesktopWindow()
      hDeskDC = GetDC(hDesk)
      BitBlt Me.hDC, 0, 0, Width, Height, hDeskDC, 0, 0, SRCCOPY

D13	Как открыть дверцу (Tray) CD-Rom программно?

Aleksandr Samsonov:
The MultiMedia function provide several commands via the mciSendString API. Perhaps one of the most frequently requested is ejecting (and loading) a CD automatically from code. Using a single line call, this is easily achieved.

Add the following code to a BAS module:

   Option Explicit

   Public Declare Function mciSendString Lib "winmm.dll" _
                  Alias "mciSendStringA" _
                  (ByVal lpstrCommand As String, _
                  ByVal lpstrReturnString As String, _
                  ByVal uReturnLength As Long, _
                  ByVal hwndCallback As Long) As Long

   Call mciSendString("Set CDAudio Door Open Wait", 0&, 0&, 0&)

   Call mciSendString("Set CDAudio Door Closed Wait", 0&, 0&, 0&)

D14	Каким образом можно засюспендить (suspend) компьютер?

Это делает функция SetSystemPowerState. Функция имеет 2 параметра, оба не задействованы в Windows 9X. В Win2000 первый параметр задает особый режим Hibernate, при котором материнская плата обесточивается, но на диммы, подается напряжение и их соедржимое рефрешится, что позволяет при включении мгновенно вернуться к прерванной работе. Материнская плата должна иметь поддержку этой возможности. Во всех предыдущих режимах hibernate, содержимое RAM записывалось на жесткий диск.
Итак, декларацию прописываем в модуль:

   Declare Function SetSystemPowerState Lib "kernel32" _
           (ByVal fSuspend As Long, ByVal fForce As Long) As Long

   SetSystemPowerState 0&, 0&

Использование внешних библиотек и дополнительных контролов.

E1	Как можно прочитать данные с порта или записать данные в порт?

Для выполнения этих функций нужно воспользоваться библиотекой DLPortIO.DLL, которая, в составе архива, находится здесь. Функции, реализованные в ней, работают под Win9X и WinNT. Архив содержит примерчик и необходимую DLL. А можно пример (без библиотеки) взять в архиве DLPortIO.
Библиотеку нужно скопировать в системный каталог Windows. Обычно это C:\WINDOWS\SYSTEM.

Базы данных.

F1	Как работать с mdb базой, расположенной на Read/Only диске (CD-Rom)?

Alexander Trishin:

   Set db = OpenDatabase (..., True, True)